Ковалев Сергей. Программирование на алгоритмическом языке MQL4
Подождите немного. Документ загружается.
181
численности 35 000? (Считать, что в месяце 30 рабочих дней.)
Решение задачи 17 реализовано в скрипте othersheep.mq4. В данном случае оператор
continue используется для расчётов во внешнем и внутреннем циклах.
//--------------------------------------------------------------------
// othersheep.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int start() // Специальная ф-ия start()
{
//--------------------------------------------------------------------
int
day, // Текущий день месяца
Mons; // Искомое количест. месяцев
double
One_Farm =1000.0, // Количество на 1 ферме
Perc_day =1, // Ежедневный подъём, %
One_Farm_max=50000.0, // Пороговое значение
Perc_exit =10, // Разовый вывод, %
Purpose =35000.0, // Необх. колич. на 2 ферме
Two_Farm; // Количество на 2 ферме
//--------------------------------------------------------------------
while(Two_Farm < Purpose) // До достижения цели
{ // Начало тела внешн. цикла
//--------------------------------------------------------------
for(day=1; day<=30 && Two_Farm < Purpose; day++)// Цикл по дням
{
One_Farm=One_Farm*(1+Perc_day/100);//Накопл. на 1 ферме
if (One_Farm < One_Farm_max) // Если меньше допустимого,.
continue; // .. то овец не переводим
Two_Farm=Two_Farm+One_Farm*Perc_exit/100;//Накопл. на 2 ферме
One_Farm=One_Farm*(1-Perc_exit/100); //Остаток на 1 ферме
}
//--------------------------------------------------------------
if (Two_Farm>=Purpose) // Если цель достигнута,..
continue; // .. то месяцы не считаем
Mons++; // Считаем месяцы
} // Конец тела внешнего цикла
//--------------------------------------------------------------------
Alert("Цель будет достигнута через ",Mons," мес. и ",day," дн.");
return; // Выход из функции start()
}
//--------------------------------------------------------------------
182
Для решения задачи необходимо анализировать количество овец для каждого дня. С этой
целью строки:
if (One_Farm < One_Farm_max) // Если меньше допустимого,.
continue; // .. то овец не переводим
Two_Farm=Two_Farm+One_Farm*Perc_exit/100;//Накопл. на 2 ферме
One_Farm=One_Farm*(1-Perc_exit/100); //Остаток на 1 ферме
перенесены во внутренний цикл, организованный по дням месяца. Очевидно, что перевод
некоторого количества овец на вторую ферму в данном случае происходит не в конце
месяца, а в тот день, когда количество овец на первой ферме достигает заданного
значения. Смысл использования здесь оператора continue тот же: "переступить" через
строки, в которых выполняются вычисления, связанные с переводом овец с одной фермы
на другую, т.е. не выполнять эти строки. Обратите внимание, цикл while, построенный по
дням месяца, не прерывается независимо от факта перевода овец, потому что действие
оператора continue распространяется на ближайший оператор цикла, в данном случае - на
оператор цикла for.
В качестве Условия в операторе цикла for используется сложное выражение:
for(day=1; day<=30 && Two_Farm<Purpose; day++)// Цикл по дням
Использование операции && ("и") означает, что цикл будет выполняться до тех пор, пока
будут справедливы оба условия:
месяц ещё не закончился, т.е. переменная day остаётся в пределах от 1 до 30
включительно;
количество овец на второй ферме не достигло заданного, т.е. переменная Two_Farm
меньше Purpose (35 000).
Если же хотя бы одно из условий не выполняется (становится ложным), цикл
прекращается. Когда выполнение цикла for закончено (по любой из причин), управление
передаётся оператору if:
if (Two_Farm >= Purpose) // Если цель достигнута,..
continue; // .. то месяцы не считаем
Mons++; // Считаем месяцы
Использование в этом месте кода оператора continue имеет простой смысл: продолжать
считать месяцы только в том случае, если количество овец на второй ферме меньше
ожидаемого. Если же цель уже достигнута, то значение переменной Mons не изменяется, а
183
управление (в результате исполнения continue) передаётся в заголовок ближайшего
оператора цикла, в этом случае - оператора цикла while.
Использование операторов continue во вложенных циклах отражено на рис. 48.
Рис. 48. Функциональная схема алгоритма, построенного на вложенных циклах. В теле
каждого из циклов имеется свой оператор continue (othersheep.mq4).
В данном примере каждый из циклов (внешний и внутренний) содержит один оператор
continue, действие которого распространяется только на "свой" ближайший цикл, а на
события в другом цикле не влияет. В общем случае в теле цикла могут использоваться
несколько операторов continue, каждый из которых может прерывать текущую итерацию в
результате выполнения какого-либо условия. Количество операторов continue в теле цикла
не ограничено.
7.7 Оператор switch
184
Некоторые программы предусматривают разветвление алгоритма по нескольким
вариантам. В подобных случаях очень удобно использовать оператор switch, особенно,
когда количество вариантов достигает десятков или сотен, а при использовании
множества вложенных операторов if код получается очень громоздким.
7.7.1 Формат оператора switch
Оператор switch состоит из заголовка и исполняемого тела. Заголовок содержит название
оператора и Выражение, обрамлённое круглыми скобками. Тело оператора содержит один
или несколько вариантов case и один вариант default.
Каждый из вариантов case состоит из ключевого слова case, Константы, ":" (знака
"двоеточие') и операторов. Количество вариантов case не ограничено.
Вариант default состоит из ключевого слова default, : (знака двоеточие) и операторов.
Обычно вариант default указывается в теле оператора switch последним, но он может
находиться и в любом другом месте тела или вообще отсутствовать.
switch ( Выражение ) // Заголовок оператора
{ // Открывающая фигурная
скобка
case Константа: Операторы // Один из вариантов case
case Константа: Операторы // Один из вариантов case
...
[default: Операторы] // Вариант без параметра
} // Закрывающая фигурная
скобка
Значениями Выражения и Параметров могут быть только значения целого типа. В
качестве Выражения может использоваться константа, переменная, вызов функции или
выражение. Каждый вариант case может быть помечен целой константой, символьной
константой или константным выражением. Константное выражение не может включать
переменные или вызовы функций.
7.7.2 Правило исполнения оператора switch
185
Передать управление первому из операторов, следующих за ":" (знаком
двоеточия) того варианта case, значение Константы которого совпадет со
значением Выражения, и далее последовательно исполнить все
операторы, составляющие тело оператора switch. Проверка условия
равенства Выражения и Константы производится в направлении сверху
вниз и слева направо. Совпадение значений Констант разных вариантов
case не допускается. Оператор break прекращает исполнение оператора
switch и передаёт управление оператору, следующему за оператором
switch.
Легко понять, что запись case Константа: представляет просто метку, на которую
передаётся управление; и, начиная с этой метки, исполняются все операторы,
составляющие тело оператора switch. Если же алгоритм программы предполагает
исполнение группы операторов, соответствующих только одному из вариантов case, то
последним в списке операторов, соответствующих одному варианту case, следует указать
оператор break. Проследим работу оператора switch на примере.
7.7.3 Примеры применения оператора switch
Задача 18. Составить программу, в которой реализуются следующие
условия: если курс поднялся выше заданного уровня, то выдать
сообщение, в котором словами обозначено превышение над уровнем (до
10 пунктов); в остальных случаях сообщить, что курс не превышает
заданный уровень.
Решение задачи с использованием оператора switch (эксперт pricealert.mq4):
//--------------------------------------------------------------------
// pricealert.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int start() // Спец. функция start
{
double Level=1.3200; // Задан. уровень цены
int Delta=NormalizeDouble((Bid-Level)Point,0); // Превышение
if (Delta<=0) // Цена не выше уровня
{
186
Alert("Цена ниже уровня"); // Сообщение
return; // Выход из start()
}
//--------------------------------------------------------------------
switch(Delta) // Заголовок switch
{ // Начало тела switch
case 1 : Alert("Плюс один пункт"); break;// Варианты..
case 2 : Alert("Плюс два пункта"); break;
case 3 : Alert("Плюс три пункта"); break;
case 4 : Alert("Плюс четыре пункта"); break;//Здесь представлено
case 5 : Alert("Плюс пять пунктов"); break;//10 вариантов case,
case 6 : Alert("Плюс шесть пунктов"); break;//но в общем случае
case 7 : Alert("Плюс семь пунктов"); break;//количество case
case 8 : Alert("Плюс восемь пунктов");break;//не ограничено
case 9 : Alert("Плюс девять пунктов");break;
case 10: Alert("Плюс десять пунктов");break;
default: Alert("Более десяти пунктов"); // С case не совпало
} // Конец тела switch
//--------------------------------------------------------------------
return; // Выход из start()
}
//--------------------------------------------------------------------
В данном варианте решения задачи используется оператор switch, в каждом варианте case
которого используется оператор break. В зависимости от значения переменной Delta
управление передаётся на один из вариантов case, в результате чего исполняются
операторы, соответствующие этому варианту: функция Alert() и оператор break. Оператор
break прекращает исполнение оператора switch, т.е. передаёт управление за его пределы, а
именно - оператору return, завершающему работу специальной функции start(). Таким
образом, в зависимости от значения переменной Delta, срабатывает один из вариантов
case, а остальные варианты оказываются не затронутыми.
Эта программа - эксперт, значит она будет запускаться в работу на каждом тике, всякий
раз отображая сообщения, соответствующие текущей ситуации. Разумеется, для
демонстрации работы программы в окне финансового инструмента необходимо подобрать
значение Level, близкое к текущему курсу.
187
Рис. 49. Функциональная схема оператора switch в эксперте pricealert.mq4.
На функциональной схеме хорошо видно, что благодаря наличию в каждом варианте case
оператора break, после исполнения операторов любого из вариантов управление
передаётся за пределы оператора switch. Подобный принцип построения алгоритма с
применением оператора switch использован и в файле stdlib.mq4, поставляемом в составе
клиентского терминала (..\experts\libraries\stdlib.mq4).
Рассмотрим другой случай, не предусматривающий использование break в каждом
варианте case.
Задача 19. Дано 10 баров. Сообщить номера всех баров, начиная с n-го.
Закодировать решение этой задачи достаточно просто (скрипт barnumber.mq4):
//--------------------------------------------------------------------
// barnumber.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int start() // Специальная функция start()
{
int n = 3; // Заданный номер
188
Alert("Номера баров, начиная с ", n,":");// Не зависит от n
//--------------------------------------------------------------------
switch (n) // Заголовок оператора switch
{ // Начало тела switch
case 1 : Alert("Бар 1"); // Варианты..
case 2 : Alert("Бар 2");
case 3 : Alert("Бар 3");
case 4 : Alert("Бар 4"); // Здесь представлено 10 ..
case 5 : Alert("Бар 5"); // ..вариантов case, но в ..
case 6 : Alert("Бар 6"); // ..общем случае количество..
case 7 : Alert("Бар 7"); // ..case не ограничено
case 8 : Alert("Бар 8");
case 9 : Alert("Бар 9");
case 10: Alert("Бар 10");break;
default: Alert("Задан неправильный номер");// С case не совпало
} // Конец тела switch
//--------------------------------------------------------------------
return; // Оператор выхода из start()
}
//--------------------------------------------------------------------
В операторе switch будет производиться перебор вариантов case до тех пор, пока не
обнаружится равенство Выражения и Константы. Когда значение Выражения (здесь - это
целое число 3) совпадает с одной из Констант (в данном случае - case 3), то исполнятся
все операторы, которые следуют за двоеточием (case 3:), а именно: оператор вызова
функции Alert("Бар 3"), следующие за ним Alert("Бар 4"), Alert("Бар 5") и т.д., пока не
встретится оператор break, завершающий работу оператора switch.
В случае если значение Выражения не совпадает ни с одной из Констант, управление
передаётся оператору, соответствующую варианту default:
189
Рис. 50. Функциональная схема оператора switch в скрипте barnumber.mq4.
В отличие от алгоритма, реализованного в предыдущей программе, в данном случае (рис.
50) в каждом варианте case не используется оператор break. Поэтому при совпадении
значения Выражения со значением одной из Констант будут исполнены все операторы,
начиная с операторов соответствующего варианта case. Использование оператора break в
последнем варианте case имеет другую цель - не допустить исполнение операторов,
соответствующих варианту default. Если же среди значений Констант не найдётся ни
одной, равной Выражению, то управление будет передано оператору, соответствующему
метке default.
Таким образом, если значение заданной переменной n находится в интервале значений от
1 до 10, то будут напечатаны номера всех баров, начиная с n, а если значение n находится
за пределами указанного диапазона, то будет выдано сообщение о несоответствии.
Обратите внимание, Константы вариантов case не обязательно должны
быть указаны в программе в порядке возрастания. Порядок следования
190
вариантов case с соответствующими Константами определяется
необходимостью программного алгоритма.
7.8 Вызов функции
Вызов функции может быть оформлен в виде отдельного оператора, а также содержаться
в любом месте программы, где по смыслу предполагается некоторое значение (за
исключением оговоренных случаев). Формат и правила исполнения вызова функции в
равной мере распространяются на стандартные (встроенные) и пользовательские функции.
7.8.1 Формат вызова функции
Вызов функции состоит из названия функции и списка передаваемых параметров,
обрамлённого круглыми скобками:
Название_функции (Список_параметров ) // Собственно вызов функции
Название, указанное в вызове функции, должно совпадать с названием функции,
вызываемой для исполнения. Список параметров указывается через запятую. Количество
параметров, передаваемых в функцию, ограничено и не может превышать 64. В качестве
параметров в вызове функции могут использоваться константы, переменные и вызовы
других функций. Количество, тип и порядок упоминания передаваемых параметров в
вызове функции должны совпадать с количеством, типом и порядком упоминания
формальных параметров, указанных в описании функции (исключение составляет вызов
функции, имеющей умолчательные параметры).
My_function (Alf, Bet) // Пример вызова функции
// Здесь:
My_function // Название вызываемой функции
Alf // Первый передаваемый параметр
Bet // Второй передаваемый параметр
Если вызываемая функция не предусматривает передаваемых параметров, то список
параметров указывается пустым, наличие круглых скобок при этом обязательно.
My_function () // Пример вызова функции
// Здесь:
My_function // Название вызываемой функции