Справочник по языку программирования MQL5

Подождите немного. Документ загружается.

Основы языка

151

Примечание: Массивы и переменные сложныхтипов не могут выступать в качестве input-

переменных.

Передача параметров при вызове пользовательских индикаторов из mql5-

программ

Пользовательские индикаторы вызываются при помощи функции iCustom(). При этом после имени

пользовательского индикатора должны идти параметры в точном соответствии с объявлением

input-переменных данного пользовательского индикатора. Если параметров указывается меньше,

чем объявлено input-переменных в вызываемом пользовательском индикаторе, то недостающие

параметры заполняются значениями, указанными при объявлении переменных.

Если в пользовательском индикаторе используется функция OnCalculate первого вида (то есть,

индикатор считается на одном массиве данных), то в качестве последнего параметра при вызове

такого пользовательского индикатора должно выступать одно из значений ENUM_APPLIED_PRICE

либо хэндл другого индикатора. При этом все параметры, соответствующие input-переменным,

должны быть явно указаны.

Перечисления в качестве input-параметра

В качестве input-переменных (входных параметров для mql5-программ) можно использовать не

только предусмотренные языком MQL5 встроенные перечисления, но и перечисления, заданные

пользователем. Например, мы можем создать перечисление dayOfWeek, описывающее дни

недели, и использовать input-переменную для указания конкретного дня недели не в виде цифры,

а в более привычном для пользователя виде.

Пример:

#property script_show_inputs

//--- day of week

enum dayOfWeek

{

S=0, // Sunday

M=1, // Monday

Основы языка

152

T=2, // Tuesday

W=3, // Wednesday

Th=4, // Thursday

Fr=5, // Friday,

St=6, // Saturday

};

//--- input parameters

input dayOfWeek swapday=W;

Для того, чтобы при запуске скрипта пользователь мог выбрать нужное значение из окна свойств,

мы используем команду препроцессора #property script_show_inputs. Запускаем скрипт на

исполнение и можем выбрать из списка одно из значений перечислений dayOfWeek. Запускаем

скрипт EnumInInput и переходим на закладку "Параметры". По умолчанию, значение параметра

swapday (день начисления тройного свопа) является среда (W=3), но мы можем задать любое

другое значение и использовать это значение для изменения работы программы.

Количество возможных значений перечисления ограничено. Поэтому для выбора входного

значения используется выпадающий список. В качестве значений, показываемых в списке,

используются мнемонические имена членов перечисления. Если же мнемоническому имени

сопоставлен комментарий, как это показано в нашем примере, то вместо мнемонического имени

используется содержимое комментария.

Каждое значение из перечисления dayOfWeek имеет свое значение от 0 до 6, но в списке

параметров будут показаны комментарии, указанные для каждого значения. Это дает

дополнительную гибкость для написания программ с понятными описаниями входных параметров.

Смотри также

iCustom, Перечисления, Свойства программ

Основы языка

153

Extern переменные

Ключевое слово extern используется, чтобы объявить идентификаторы переменных как

идентификаторы статическогоклассапамяти с глобальным временемжизни. Такие переменные

существуют с момента начала выполнения программы и для них память выделяется и

инициализируется сразу после начала выполнения программы.

Можно создавать программы, которые состоят из нескольких исходных файлов, для этого

используется директива препроцессору #include. Переменные, объявленные как extern с одним и

тем же типом и идентификатором, могут существовать в разных исходных файлах одного

проекта.

При компиляции всего проекта все extern-переменные с одним и тем же типом и

идентификатором ассоциируются с одним участком памяти пула глобальных переменных. Extern-

переменные полезны для раздельной компиляции исходных файлов. Extern-переменные можно

инициализировать, но только однократно – недопустимо существование нескольких

инициализированных extern-переменных одного и того же типа и с одним и тем же

идентификатором.

Смотри также

Типы данных, Инкапсуляция и расширяемость типов, Инициализация переменных, Область

видимости и время жизни переменных, Создание и уничтожение объектов

Основы языка

154

Инициализация переменных

Любая переменная при определении может быть инициализирована. Если не произведена явная

инициализация переменной, то значение, хранящееся в данной переменной, может быть каким

угодно. Неявная инициализация не производится.

Глобальные и статические переменные могут быть проинициализированы только константой

соответствующего типа или константным выражением. Локальныепеременные могут быть

проинициализированы любым выражением, а не только константой.

Инициализация глобальных и статических переменных производится однократно. Инициализация

локальных переменных производится каждый раз при вызове соответствующих функций.

Примеры:

int n = 1;

string s = "hello";

double f[] = { 0.0, 0.236, 0.382, 0.5, 0.618, 1.0 };

int a[4][4] = { {1, 1, 1, 1}, {2, 2, 2, 2}, {3, 3, 3, 3}, {4, 4, 4, 4 } };

//--- из тетриса

int right[4]={WIDTH_IN_PIXELS+VERT_BORDER,WIDTH_IN_PIXELS+VERT_BORDER,

WIDTH_IN_PIXELS+VERT_BORDER,WIDTH_IN_PIXELS+VERT_BORDER};

Список значений элементов массива должен быть заключен в фигурные скобки. Пропущенные

инициализирующие последовательности считаются равными 0. В инициализирующей

последовательности должно быть хотя бы одно значение: этим значением инициализируется

первый элемент соответствующей структуры или массива, отсутствующие элементы считаются

равными нулю.

Если размер инициализируемого массива не указан, то он определяется компилятором, исходя из

размера инициализирующей последовательности. Многомерные массивы не могут

инициализироваться одномерной последовательностью (последовательностью без

дополнительных фигурных скобок), за исключением одного случая – когда указывается всего

один инициализирующий элемент (как правило, ноль).

Массивы (в том числе и объявленные на локальном уровне) могут инициализироваться только

константами.

Примеры:

Основы языка

155

struct str3

{

int low_part;

int high_part;

};

struct str10

{

str3 s3;

double d1[10];

int i3;

};

void OnStart()

{

str10 s10_1={{1,0},{1.0,2.1,3.2,4.4,5.3,6.1,7.8,8.7,9.2,10.0},100};

str10 s10_2={{1,0},{0},100};

str10 s10_3={{1,0},{1.0}};

//---

Print("1. s10_1.d1[5] = ",s10_1.d1[5]);

Print("2. s10_2.d1[5] = ",s10_2.d1[5]);

Print("3. s10_3.d1[5] = ",s10_3.d1[5]);

Print("4. s10_3.d1[0] = ",s10_3.d1[0]);

}

Смотри также

Типы данных, Инкапсуляция и расширяемость типов, Область видимости и время жизни

переменных, Создание и уничтожение объектов

Основы языка

156

Область видимости и время жизни переменных

Существует два основных вида области видимости: локальная область видимости и глобальная

область видимости.

Переменная, объявленная вне всех функций, помещается в глобальную область видимости.

Доступ к таким переменным может осуществляться из любого места программы. Такие

переменные располагаются в глобальном пуле памяти, поэтому время их жизни совпадает со

временем жизни программы.

Переменная, объявленная внутри блока (часть кода, заключенная в фигурные скобки),

принадлежит локальной области видимости. Такая переменная не видна (поэтому и недоступна)

за пределами блока, в котором она объявлена. Самый распространенный случай локального

объявления – переменная, объявленная внутри функции. Переменная, объявленная локально,

располагается на стеке, и время жизни такой переменной совпадает со временем жизни функции.

Так как областью видимости локальной переменной является блок, в котором она объявлена, то

существует возможность объявлять переменные с именем, совпадающим с именами переменных,

объявленных в других блоках; а также объявленных на более верхних уровнях, вплоть до

глобального.

Пример:

Основы языка

157

void CalculateLWMA(int rates_total,int prev_calculated,int begin,const double &price[])

{

int i,limit;

static int weightsum=0;

double sum=0;

//---

if(prev_calculated==0)

{

limit=MA_Period+begin;

//--- set empty value for first limit bars

for(i=0; i<limit; i++) LineBuffer[i]=0.0;

//--- calculate first visible value

double firstValue=0;

for(int i=begin; i<limit; i++)

{

int k=i-begin+1;

weightsum+=k;

firstValue+=k*price[i];

}

firstValue/=(double)weightsum;

LineBuffer[limit-1]=firstValue;

}

else

{

limit=prev_calculated-1;

}

for(i=limit;i<rates_total;i++)

{

sum=0;

for(int j=0; j<MA_Period; j++) sum+=(MA_Period-j)*price[i-j];

LineBuffer[i]=sum/weightsum;

}

//---

}

Обратите внимание на переменную i, объявленную в строке

for(int i=begin; i<limit; i++)

{

int k=i-begin+1;

weightsum+=k;

firstValue+=k*price[i];

}

Ее область видимости – только цикл for, за пределами этого цикла действует другая переменная с

тем же именем, объявленная в начале функции. Кроме того, в теле цикла объявлена переменная

k, областью видимости которой является тело цикла.

Локальные переменные можно объявлять со спецификатором доступа static. В этом случае

компилятор располагает такую переменную в глобальном пуле памяти. Поэтому, время жизни

статической переменной совпадает со временем жизни программы. При этом область видимости

такой переменной ограничивается пределами блока, в котором она объявлена.

Смотри также

Типы данных, Инкапсуляция и расширяемость типов, Инициализация переменных, Создание и

уничтожение объектов

Основы языка

158

Создание и уничтожение объектов

После загрузки на исполнение mql5-программы каждой переменной выделяется память в

соответствие с типом переменной. Переменные делятся на два типа по уровню доступа -

глобальные переменные и локальные переменные, и по классам памяти: входные параметры

mql5-программы, статические и автоматические. Каждая переменная при необходимости

инициализируется соответствующим значением. После использования переменная

деинициализируется и память, использованная ею, возвращается исполняемой системе MQL5.

Инициализация и деинициализация глобальных переменных

Инициализация глобальных переменных производится автоматически сразу после загрузки mql5-

программы и до вызова любой функции. При инициализации производится присвоение начальных

значений переменным простых типов и вызывается конструктор для объектов, если он есть.

Входные переменные всегда объявляются на глобальном уровне, инициализируются значениями,

задаваемыми пользователями в диалоге при запуске mql5-программы.

Несмотря на то, что статические переменные обычно объявляются на локальном уровне, память

под эти переменные распределяется заранее, и инициализация производится сразу после загрузки

программы, точно так же как и для глобальных переменных.

Порядок инициализации соответствует порядку объявления переменной в программе, а

деинициализации производится в обратном порядке перед выгрузкой mql5-программы. Это

правило только для тех переменных, которые не были созданы оператором new. Такие

переменные создаются и инициализируются автоматически сразу после загрузки, а

деинициализируются непосредственно перед выгрузкой программы.

Инициализация и деинициализация локальных переменных

Если переменная, объявленная на локальном уровне не является статической, то распределение

памяти под такую переменную производится автоматически. Локальные переменные, также как и

глобальные, инициализируются автоматически в тот момент, когда выполнение программы

встречает объявление локальной переменной. Таким образом, порядок инициализации

соответствует порядку объявления.

Локальные переменные деинициализируются в конце блока программы, в котором они

объявлены, и в порядке, обратном их объявлению. Блок программы – это составной оператор,

который может являться частью оператора выбора switch, цикла(for, while, do-while), телом

функции или частью оператора if-else.

Инициализация локальных переменных происходит только в тот момент, когда выполнение

программы доходит до объявления переменной. Если в процессе выполнения программы блок, в

котором объявлена переменная, не был выполнен, то такая переменная не инициализируется.

Инициализация и деинициализация динамически размещаемых

объектов

Особый случай представляет из себя указатели объектов, так как объявление указателя не влечет

за собой инициализации соответствующего объекта. Динамически размещаемые объекты

инициализируются только в момент создания экземпляра класса оператором new. Инициализация

Основы языка

159

объекта предполагает вызов конструктора соответствующего класса. Если соответствующего

конструктора в классе нет, то его члены, имеющие простой тип, не будут автоматически

проинициализированы; члены типов строка, динамический массив и сложный объект будут

автоматически проинициализированы.

Указатели могут быть объявлены на локальном или глобальном уровне, и при этом могут быть

проинициализированы пустым значением NULL или значением указателя такого же или

порожденного типа. Если для указателя, объявленного на локальном уровне, был вызван

оператор new, то и оператор delete для этого указателя должен быть выполнен до выхода из

этого уровня. В противном случае указатель будет потерян и объект не сможет быть удален явно.

Все объекты, созданные выражением указатель_объекта=new Имя_Класса, обязательно

должны быть впоследствии уничтожены оператором delete(указатель_объекта). Если по каким

то причинам такая переменная по окончании работы программы не была уничтожена оператором

delete, то об этом будет выведено сообщение в журнал "Эксперты". Можно объявить несколько

переменных, и всем им присвоить указатель одного объекта.

Если динамически создаваемый объект имеет конструктор, то этот конструктор будет вызван в

момент выполнения оператора new. Если объект имеет деструктор, то деструктор будет вызван в

момент выполнения оператора delete.

Таким образом, динамически размещаемые объекты создаются только в момент создания

оператором new, и гарантированно уничтожаются либо оператором delete либо автоматически

исполняющей системой MQL5 в момент выгрузки программы. Порядок объявления указателей

динамически создаваемых объектов не влияет на порядок их инициализации. Порядок

инициализации и деинициализации полностью контролируется программистом.

Краткая характеристика переменных

Основные сведения о порядке создания, уничтожении, вызове конструкторов и деструкторов

приведены в краткой таблице.

Глобальная

автоматическая

переменная

Локальная

автоматическая

переменная

Динамически

создаваемый

объект

Инициализация

сразу после загрузки

mql5-программы

при достижении в

ходе выполнения

строки кода, где она

объявлена

при выполнении

оператора new

Порядок

инициализации

в порядке

объявления

в порядке

объявления

не зависит от

порядка объявления

Деинициализация

перед выгрузкой

mql5-программы

при выходе

выполнения из блока

объявления

при выполнении

оператора delete или

перед выгрузкой

mql5-программы

Порядок

деинициализации

в порядке, обратном

инициализации

в порядке, обратном

инициализации

не зависит от

порядка

инициализации

Основы языка

160

Вызов

конструктора

при загрузке mql5-

программы

при инициализации

при выполнении

оператора new

Вызов деструктора

при выгрузке mql5-

программы

при выходе из блока,

в котором

переменная была

инициализирована

при выполнении

оператора delete

Сообщения об

ошибках

сообщение в журнал

"Эксперты" о попытке

удаления

автоматически

созданного объекта

сообщение в журнал

"Эксперты" о попытке

удаления

автоматически

созданного объекта

сообщение в журнал

"Эксперты" о

неудаленных

динамически

созданных объектах

при выгрузке mql5-

программы

Смотри также

Типы данных, Инкапсуляция и расширяемость типов, Инициализация переменных, Область

видимости и время жизни переменных