Язык программирования MQL4
Подождите немного. Документ загружается.
со значением Выражения, и далее последовательно исполнить все
операторы, составляющие тело оператора switch. Проверка условия
равенства Выражения и Константы производится в направлении
сверху вниз и слева направо. Совпадение значений Констант разных
вариантов case не допускается. Оператор break прекращает исполнение
оператора switch и передаёт управление оператору, следующему за
оператором switch.
Легко понять, что запись case Константа: представляет просто метку, на которую
передаётся управление; и, начиная с этой метки, исполняются все операторы,
составляющие тело оператора switch. Если же алгоритм программы предполагает
исполнение группы операторов, соответствующих только одному из вариантов case, то
последним в списке операторов, соответствующих одному варианту case, следует указать
оператор break. Проследим работу оператора switch на примере.
7.7.3 Примеры применения оператора switch
Задача 18. Составить программу, в которой реализуются следующие
условия: если курс поднялся выше заданного уровня, то выдать
сообщение, в котором словами обозначено превышение над уровнем
(до 10 пунктов); в остальных случаях сообщить, что курс не
превышает заданный уровень.
Решение задачи с использованием оператора switch (эксперт pricealert.mq4):
//--------------------------------------------------------------------
// pricealert.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int start() // Спец. функция start
{
double Level=1.3200; // Задан. уровень цены
int Delta=NormalizeDouble((Bid-Level)Point,0); // Превышение
if (Delta<=0) // Цена не выше уровня
{
Alert("Цена ниже уровня"); // Сообщение
return; // Выход из start()
}
//--------------------------------------------------------------------
switch(Delta) // Заголовок switch
181
{ // Начало тела switch
case 1 : Alert("Плюс один пункт"); break;// Варианты..
case 2 : Alert("Плюс два пункта"); break;
case 3 : Alert("Плюс три пункта"); break;
case 4 : Alert("Плюс четыре пункта"); break;//Здесь представлено
case 5 : Alert("Плюс пять пунктов"); break;//10 вариантов case,
case 6 : Alert("Плюс шесть пунктов"); break;//но в общем случае
case 7 : Alert("Плюс семь пунктов"); break;//количество case
case 8 : Alert("Плюс восемь пунктов");break;//не ограничено
case 9 : Alert("Плюс девять пунктов");break;
case 10: Alert("Плюс десять пунктов");break;
default: Alert("Более десяти пунктов"); // С case не совпало
} // Конец тела switch
//--------------------------------------------------------------------
return; // Выход из start()
}
//--------------------------------------------------------------------
В данном варианте решения задачи используется оператор switch, в каждом варианте case
которого используется оператор break. В зависимости от значения переменной Delta
управление передаётся на один из вариантов case, в результате чего исполняются
операторы, соответствующие этому варианту: функция Alert() и оператор break. Оператор
break прекращает исполнение оператора switch, т.е. передаёт управление за его пределы, а
именно - оператору return, завершающему работу специальной функции start(). Таким
образом, в зависимости от значения переменной Delta, срабатывает один из вариантов
case, а остальные варианты оказываются не затронутыми.
Эта программа - эксперт, значит она будет запускаться в работу на каждом тике, всякий
раз отображая сообщения, соответствующие текущей ситуации. Разумеется, для
демонстрации работы программы в окне финансового инструмента необходимо подобрать
значение Level, близкое к текущему курсу.
182
Рис. 49. Функциональная схема оператора switch в эксперте pricealert.mq4.
На функциональной схеме хорошо видно, что благодаря наличию в каждом варианте case
оператора break, после исполнения операторов любого из вариантов управление
передаётся за пределы оператора switch. Подобный принцип построения алгоритма с
применением оператора switch использован и в файле stdlib.mq4, поставляемом в составе
клиентского терминала (..\experts\libraries\stdlib.mq4).
Рассмотрим другой случай, не предусматривающий использование break в каждом
варианте case.
Задача 19. Дано 10 баров. Сообщить номера всех баров, начиная с n-го.
Закодировать решение этой задачи достаточно просто (скрипт barnumber.mq4):
//--------------------------------------------------------------------
// barnumber.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int start() // Специальная функция start()
{
int n = 3; // Заданный номер
Alert("Номера баров, начиная с ", n,":");// Не зависит от n
//--------------------------------------------------------------------
183
switch (n) // Заголовок оператора switch
{ // Начало тела switch
case 1 : Alert("Бар 1"); // Варианты..
case 2 : Alert("Бар 2");
case 3 : Alert("Бар 3");
case 4 : Alert("Бар 4"); // Здесь представлено 10 ..
case 5 : Alert("Бар 5"); // ..вариантов case, но в ..
case 6 : Alert("Бар 6"); // ..общем случае количество..
case 7 : Alert("Бар 7"); // ..case не ограничено
case 8 : Alert("Бар 8");
case 9 : Alert("Бар 9");
case 10: Alert("Бар 10");break;
default: Alert("Задан неправильный номер");// С case не совпало
} // Конец тела switch
//--------------------------------------------------------------------
return; // Оператор выхода из start()
}
//--------------------------------------------------------------------
В операторе switch будет производиться перебор вариантов case до тех пор, пока не
обнаружится равенство Выражения и Константы. Когда значение Выражения (здесь - это
целое число 3) совпадает с одной из Констант (в данном случае - case 3), то исполнятся
все операторы, которые следуют за двоеточием (case 3:), а именно: оператор вызова
функции Alert("Бар 3"), следующие за ним Alert("Бар 4"), Alert("Бар 5") и т.д., пока не
встретится оператор break, завершающий работу оператора switch.
В случае если значение Выражения не совпадает ни с одной из Констант, управление
передаётся оператору, соответствующую варианту default:
184
Рис. 50. Функциональная схема оператора switch в скрипте barnumber.mq4.
В отличие от алгоритма, реализованного в предыдущей программе, в данном случае (рис.
50) в каждом варианте case не используется оператор break. Поэтому при совпадении
значения Выражения со значением одной из Констант будут исполнены все операторы,
начиная с операторов соответствующего варианта case. Использование оператора break в
последнем варианте case имеет другую цель - не допустить исполнение операторов,
соответствующих варианту default. Если же среди значений Констант не найдётся ни
одной, равной Выражению, то управление будет передано оператору, соответствующему
метке default.
Таким образом, если значение заданной переменной n находится в интервале значений от
1 до 10, то будут напечатаны номера всех баров, начиная с n, а если значение n находится
за пределами указанного диапазона, то будет выдано сообщение о несоответствии.
Обратите внимание, Константы вариантов case не обязательно должны
быть указаны в программе в порядке возрастания. Порядок следования
вариантов case с соответствующими Константами определяется
185
необходимостью программного алгоритма.
7.8 Вызов функции
Вызов функции может быть оформлен в виде отдельного оператора, а также содержаться
в любом месте программы, где по смыслу предполагается некоторое значение (за
исключением оговоренных случаев). Формат и правила исполнения вызова функции в
равной мере распространяются на стандартные (встроенные) и пользовательские функции.
7.8.1 Формат вызова функции
Вызов функции состоит из названия функции и списка передаваемых параметров,
обрамлённого круглыми скобками:
Название_функции (Список_параметров ) // Собственно вызов функции
Название, указанное в вызове функции, должно совпадать с названием функции,
вызываемой для исполнения. Список параметров указывается через запятую. Количество
параметров, передаваемых в функцию, ограничено и не может превышать 64. В качестве
параметров в вызове функции могут использоваться константы, переменные и вызовы
других функций. Количество, тип и порядок упоминания передаваемых параметров в
вызове функции должны совпадать с количеством, типом и порядком упоминания
формальных параметров, указанных в описании функции (исключение составляет вызов
функции, имеющей умолчательные параметры).
My_function (Alf, Bet) // Пример вызова функции
// Здесь:
My_function // Название вызываемой функции
Alf // Первый передаваемый параметр
Bet // Второй передаваемый параметр
Если вызываемая функция не предусматривает передаваемых параметров, то список
параметров указывается пустым, наличие круглых скобок при этом обязательно.
My_function () // Пример вызова функции
// Здесь:
My_function // Название вызываемой функции
// Передаваемые параметры
отсутствуют
186
При вызове функции, имеющей умолчательные параметры, список передаваемых
параметров может быть ограничен (указан не полностью). Список параметров можно
ограничить, начиная с первого умолчательного параметра. В данном примере локальные
переменные b, c и d имеют умолчательные значения.
// Для функции с описанием:
int My_function (int a, bool b=true, int c=1, double d=0.5)
{
Операторы
}
// .. допустимы следующие вызовы:
My_function (Alf, Bet, Ham, Del) // Допустимый вызов функции
My_function (Alf ) // Допустимый вызов функции
My_function (3) // Допустимый вызов функции
My_function (Alf, 0) // Допустимый вызов функции
My_function (3, Tet) // Допустимый вызов функции
My_function (17, Bet, 3) // Допустимый вызов функции
My_function (17, Bet, 3, 0.5) // Допустимый вызов функции
Параметры, не имеющие значения по умолчанию, опускать нельзя. Если какой-либо из
умолчательных параметров опущен, то все последующие умолчательные параметры также
не указываются.
// Для функции с описанием:
int My_function (int a, bool b=true, int c=1, double d=0.5)
{
Операторы
}
// ..следующие вызовы являются
ошибочными:
My_function () // Недопустимый вызов функции:
неумолчательные..
// ..параметры опускать нельзя
(первый)
My_function (17, Bet, , 0.5) // Недопустимый вызов функции:
пропущен..
// ..умолчательный параметр
(третий)
Вызываемые функции делятся на две группы: возвращающие некоторое значение заранее
определённого типа и не возвращающие никакого значения.
7.8.2 Формат вызова функции, не возвращающей значение
187
Вызов функции, не возвращающей значение, может быть оформлен только в виде
отдельного оператора. Оператор вызова функции заканчивается знаком ; (точка с
запятой):
Название_функции (Список_параметров ); // Оператор вызова функции,не
возвращающей знач
Func_no_ret (Alfa, Betta, Gamma); // Пример оператора вызова функции,..
//.. не возвращающей значение
Иного формата (способа) для вызова функций, не возвращающих значение, не
предусмотрено.
7.8.3 Формат вызова функции, возвращающей значение
Вызов функции, возвращающей значение, может быть оформлен в виде отдельного
оператора, а также использоваться в коде программы - в том месте, где по смыслу
предполагается значение известного типа.
В случае оформления в виде отдельного оператора вызов функции заканчивается знаком ;
(точка с запятой):
Название_функции (Список_параметров ); // Оператор вызова функции,
возвращающей знач
Func_yes_ret (Alfa, Betta, Delta); // Пример оператора вызова функции,..
//.. возвращающей значение
7.8.4 Правила исполнения вызова функции
Вызов функции вызывает для исполнения одноимённую функцию.
Если вызов функции оформлен в виде отдельного оператора, то после
исполнения функции управление передаётся оператору, следующему
за вызовом функции. Если вызов функции используется в выражении,
то после исполнения функции управление передаётся в то место
выражения, где указан вызов функции, и дальнейшие вычисления в
выражении производятся со значением, возвращённым функцией.
Использование вызова функции в составе других операторов определяется форматом этих
операторов.
188
Задача 20. Составить программу, в которой реализуются следующие
условия: - если текущее время больше 15:00, то выполнить 10
итераций в цикле for;- в остальных случаях выполнить 6 итераций.
Ниже приведен пример скрипта callfunction.mq4, в котором используются: вызов функции
в заголовке оператора for (в составе Выражения_1, согласно формату оператора for, см.
Оператор цикла for), вызов стандартной функции в виде отдельного оператора, в правой
части оператора присваивания (см. Оператор присваивания) и в заголовке оператора if-
else (в Условии, согласно формату оператора if-else, см. Условный оператор if-else).
///--------------------------------------------------------------------
// callfunction.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int start() // Описание функции start()
{ // Начало тела ф-ии start()
int n; // Объявление переменной
int T=15; // Заданное время
for(int i=Func_yes_ret(T);i<=10;i++) // Использование функции в..
//.заголовке оператора цикла
{ // Начало тела цикла for
n=n+1; // Счётчик итераций
Alert ("Итерация n=",n," i=",i); // Оператор вызова функции
} // Конец тела цикла for
return; // Выход из функции start()
} // Конец тела ф-ии start()
//--------------------------------------------------------------------
int Func_yes_ret (int Times_in) // Описание пользоват. ф-ии
{ // Начало тела польз. ф-ии
datetime T_cur=TimeCurrent(); // Использование функции в..
// ..операторе присваивания
if(TimeHour(T_cur) > Times_in) // Использование функции в..
//..заголовке операт.if-else
return(1); // Возврат значения 1
return(5); // Возврат значения 5
} // Конец тела пользов. ф-ии
//--------------------------------------------------------------------
В приведенном примере использованы вызовы следующих функций с такими
передаваемыми параметрами:
в вызове функции Func_yes_ret(T) - переменная T;
в вызове функции Alert () - строковые константы "Итерация n=" и " i=", переменные n и i;
189
вызов функции TimeCurrent() не предусматривает передаваемых параметров;
в вызове функции TimeHour(T_cur) - переменная T_cur.
В программе реализован очень простой алгоритм. В переменной Т задаётся время в часах,
относительно которого производятся вычисления. В заголовке оператора for указан вызов
пользовательской функции Func_yes_ret(), которая может возвращать одно из двух
значений: 1 или 5. В зависимости от этого значения изменяется количество итераций в
цикле: либо их будет 10 (i изменяется от 1 до 10), либо 6 (i изменяется от 5 до 10). Для
наглядности в теле цикла используется счётчик итераций, каждое значение которого
выводится на экран с помощью функции Alert().
В описании пользовательской функции сначала вычисляется время в секундах,
прошедших после 00:00 1 января 1970 года (обращение к функции TimeCurrent()), а затем
текущее время в часах (обращение к функции TimeHour()). Разветвление алгоритма
осуществляется с помощью оператора if (вызов функции TimeHour() указан в его
условии). Если текущее время оказывается больше, чем переданное в пользовательскую
функцию (локальная переменная Times_in), то пользовательская функция возвращает 1,
иначе - возвращает 5.
Обратите внимание:
В программе нет описаний стандартных функций и вызова
специальной функции start().
Ниже показана функциональная схема скрипта callfunction.mq4:
190