Язык программирования MQL4

13.1.1 Использование включаемых файлов

Если прикладная программа содержит множество программных строк, то её отладка

бывает затруднительной - программисту приходится многократно прокручивать текст

программы, чтобы внести изменения в код в том или ином месте. В подобных случаях для

удобства программа может быть разделена на несколько фрагментов, каждый из которых

оформляется в виде отдельного включаемого файла. Включаемые файлы могут содержать

любой фрагмент кода, который предполагается использовать в программе. Обычно

каждая используемая в программе функция оформляется в виде включаемого файла. Если

несколько функций логически связаны между собой, то содержанием одного включаемого

файла может быть описание нескольких пользовательских функций.

В разделе Информация о счёте рассматривался пример защитного кода,

предотвращающего несанкционированное использование коммерческих программ. В

эксперте check.mq4 соответствующая часть программного кода представлена в виде

пользовательской функции Check(), описание которой содержится непосредственно в

исходном тексте эксперта. В эксперте usualexpert.mq4 (см. рис. 91.3) также используется

эта функция, но в этом случае функция оформлена в виде включаемого файла Check.mqh.

13.1.2 Пользовательская функция Check()

bool Check()

Функция возвращает TRUE, если соблюдены условия использования прикладной

программы, возвращает FALSE, если условия не соблюдены.

Условия использования программы считаются выполненными, если:

программа используется на демо-счёте;

счёт открыт в компании SuperBank;

при работе на реальном счёте пользователь установил правильное значение внешней

переменной Parol.

Включаемый файл Check.mqh, содержащий описание пользовательской функции Check():

//--------------------------------------------------------------------

// Check.mqh

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------- 1 --

// Функция проверки легальности использования программы

871

// Входные параметры:

// - глобальная переменная Parol

// - локальная константа "SuperBank"

// Возвращаемые значения:

// true - если условия использования соблюдены

// false - если условия использования нарушены

//--------------------------------------------------------------- 2 --

extern int Parol=12345; // Пароль для работы на реальном счёте

//--------------------------------------------------------------- 3 --

bool Check() // Пользовательская функция

{

if (IsDemo()==true) // Если это демо-счёт, то..

return(true); // .. других ограничений нет

if (AccountCompany()=="SuperBank") // Для корпоративных клиентов..

return(true); // ..пароль не нужен

int Key=AccountNumber()*2+1000001; // Вычисляем ключ

if (Parol==Key) // Если пароль верный, то..

return(true); // ..разрешаем работу на реале

Inform(14); // Сообщение о несанкц. работе

return(false); // Выход из пользов. функции

}

//--------------------------------------------------------------- 4 --

Легко заметить, что название включаемого файла совпадает с названием содержащейся в

нём функции. Правилами языка MQL4 такое требование не предусмотрено. В общем

случае название включаемого файла не обязательно должно совпадать с названием

функции, которая в нём содержится. Тем более это понятно, если учесть, что один файл

может нести описание нескольких функций или какого-либо фрагмента программы,

вообще не являющегося функцией. Однако практика присваивать включаемому файлу

имя, совпадающее с именем описанной в нём функции, оправданна. При этом значительно

облегчается труд программиста: он легко может понять, какие функции имеются в

каталоге Каталог_терминала\experts\include, ориентируясь по именам файлов. Для того

чтобы фрагмент программы, содержащийся в файле, включить в программу, используется

директива #include.

13.1.3 Директива #include

#include <Имя файла>

#include "Имя файла"

872

Директива #include может быть указана в любом месте программы, но обычно все

включения размешаются в начале файла исходного текста. Препроцессор заменяет строку

#include <имя_файла> (или строку #include "имя_файла") содержимым файла с указанным

именем.

Угловые скобки обозначают, что файл будет взят из стандартного каталога

Каталог_терминала\experts\include (текущий каталог не просматривается). Если имя

файла заключено в кавычки, то поиск производится в текущем каталоге, а именно в том, в

котором содержится основной файл исходного текста (стандартный каталог не

просматривается).

Ниже представлен обычный эксперт usualexpert.mq4. Все включаемые файлы размещены

в головной части программы.

//--------------------------------------------------------------------

// usualexpert.mq4

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------- 1 --

#property link "http://AutoGraf.dp.ua"

//--------------------------------------------------------------- 2 --

#include <stdlib.mqh>

#include <stderror.mqh>

#include <WinUser32.mqh>

//--------------------------------------------------------------- 3 --

#include <Variables.mqh> // Описание переменных

#include <Check.mqh> // Проверка легальности использов. программ

#include <Terminal.mqh> // Учёт ордеров

#include <Events.mqh> // Функция слежения за событиями, обновлен.

#include <Inform.mqh> // Информационная функция

#include <Trade.mqh> // Торговая функция

#include <Open_Ord.mqh> // Открытие одного ордера заданного типа

#include <Close_All.mqh> // Закрытие всех ордеров заданного типа

#include <Tral_Stop.mqh> // Модификация StopLoss всех ордеров типа

#include <Lot.mqh> // Вычисление количества лотов

#include <Criterion.mqh> // Торговые критерии

#include <Errors.mqh> // Функция обработки ошибок.

//--------------------------------------------------------------- 4 --

int init() // Спец. функция init

{

Level_old=MarketInfo(Symbol(),MODE_STOPLEVEL );//Миним. дистаниция

Terminal(); // Функция учёта ордеров

return; // Выход из init()

}

//--------------------------------------------------------------- 5 --

873

int start() // Спец. функция start

{

if(Check()==false) // Если условия использования..

return; // ..не выполняются, то выход

PlaySound("tick.wav"); // На каждом тике

Terminal(); // Функция учёта ордеров

Events(); // Информация о событиях

Trade(Criterion()); // Торговая функция

Inform(0); // Для перекрашивания объектов

return; // Выход из start()

}

//--------------------------------------------------------------- 6 --

int deinit() // Спец. функция deinit()

{

Inform(-1); // Для удаления объектов

return; // Выход из deinit()

}

//--------------------------------------------------------------- 7 --

В блоке 2-3 с помощью директивы #include в программу включены стандартные файлы

stdlib.mqh, stderror.mqh и WinUser32.mqh. Использование этих файлов в программе бывает

необходимо не всегда. Например, файл stderror.mqh содержит определение стандартных

констант, используемых при обработке ошибок. Если в программе не предусмотрен

анализ ошибок (указанные константы не используются), то включать этот фал в исходный

текст нет необходимости. Вместе с тем, в обычной программе, как правило, требуется

использование указанных файлов.

В блоке 3-4 в программу включены несколько файлов, содержащих описание

пользовательских функций. В том числе, с помощью директивы #include, в строке:

#include <Check.mqh> // Проверка легальности использов. программ

в исходный текст программы включается пользовательская функция Check().

Программист видит исходный текст эксперта (в данном случае - usualexpert.mq4) таким,

каким он представлен выше. Однако при компиляции исходный текст программы

преобразуется, а именно: вместо каждой строки, содержащей директиву #include, в

программу вставляется текст, содержащийся в файле с указанным именем. Таким

образом, исполняемый файл .ex4 создаётся на основе полного кода эксперта, в котором

вместо каждой строки #include<Имя файла> (или #include "Имя файла") содержится

соответствующий фрагмент кода.

874

Примером включаемого файла, в котором содержится некоторый фрагмент программы, не

являющийся описанием функции, может служить файл Variables.mqh. Этот файл

включается в текст программы в строке:

#include <Variables.mqh> // Описание переменных

и содержит описание глобальных переменных, которые используются различными

пользовательскими функциями.

//--------------------------------------------------------------------

// Variables.mqh

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------- 1 --

// Описание глобальных переменных

extern double Lots = 0.0;// Количество лотов

extern int Percent = 0; // Процент выделенных средств

extern int StopLoss =100; // StopLoss для новых ордеров (пунктов)

extern int TakeProfit =40; // TakeProfit для новых ордеров (пунктов)

extern int TralingStop=100; // TralingStop для рыночных ордеров (пунк)

//--------------------------------------------------------------- 2 --

int

Level_new, // Новое значение минимальной дистанции

Level_old, // Предыдущее значение минимальной дистанции

Mas_Tip[6]; // Массив типов ордеров

// [] тип орд: 0=B,1=S,2=BL,3=SL,4=BS,5=SS

//--------------------------------------------------------------- 3 --

double

Lots_New, // Количество лотов для новых ордеров

Mas_Ord_New[31][9], // Массив ордеров текущий ..

Mas_Ord_Old[31][9]; // .. и старый

// 1й индекс = порядковый номер ордера

// [][0] не определяется

// [][1] курс откр. ордера (абс.знач.курса)

// [][2] StopLoss ордера (абс.знач.курса)

// [][3] TakeProfit ордера (абс.знач.курса)

// [][4] номер ордера

// [][5] колич. лотов орд. (абс.знач.курса)

// [][6] тип орд. 0=B,1=S,2=BL,3=SL,4=BS,5=SS

// [][7] магическое число ордера

// [][8] 0/1 факт наличия комментария

//--------------------------------------------------------------- 4 --

В соответствии с правилами MQL4 объявление любой, в том числе и глобальной,

переменной должно осуществляться до первого обращения к этой переменной. По этой

причине файл Variables.mqh включён в программу раньше (выше по тексту), чем файлы

875

функций, использующих значения указанных в этом файле переменных. По этой же

причине в этот файл вынесены все глобальные переменные.

В некоторых (редких) случаях имеется техническая возможность объявить глобальную

переменную во включаемом файле, описывающем функцию, в которой впервые в

программе используется значение этой переменной. В таких случаях необходимо следить

за порядком включения файлов. Т.е. требуется, чтобы программная строка с директивой

#include, включающей файл (с объявлением глобальной переменной) в программу,

находилась выше по тексту, чем строки, включающие другие файлы, где используется

значение этой глобальной переменной.

В других случаях нет даже указанной технической возможности. Например, если имеется

два включаемых файла, каждый из которых использует две глобальные переменные, одна

из которых объявлена в одном файле, а другая в другом, то при компиляции такой

программы будет получена ошибка, т.к. независимо от порядка включения файлов одна из

переменных используется раньше, чем она объявлена в программе. Поэтому, обычная

практика объявления глобальных переменных в обычной программе предполагает

объявление всех без исключения глобальных переменных в одном файле, который

включается в программу раньше других файлов, содержащих описание пользовательских

функций.

В блоке 1-2 включаемого файла Variables.mqh указаны внешние переменные, значения

которых определяют количество лотов для новых ордеров, процент свободных средств,

выделенный для новых ордеров, заявленные цены для стоп-приказов открываемых

рыночных ордеров, а также дистанцию TralingStop для модификации StopLoss ордера. В

блоках 2-4 указаны другие глобальные переменные, смысл которых будет понятен при

рассмотрении соответствующих пользовательских функций. В следующих разделах главы

представлены включаемые файлы, каждый из которых содержит описание одноимённой

пользовательской функции

13.2 Учёт ордеров

Ранее упоминалось, что каких-либо жёстких правил для составления алгоритмов

программ не существует. Вместе с тем, подавляющее большинство алгоритмов

предполагает принятие торговых решений в зависимости от текущего состояния ордеров.

В одних случаях, например, для открытия рыночного ордера требуется, чтобы на момент

876

осуществления торговой операции других рыночных ордеров не было. В других случаях,

для установки отложенного ордера необходимым условием может являться отсутствие

стоп-приказов на рыночном ордере. Известны также алгоритмы, предполагающие

установку одновременно двух разнонаправленных отложенных ордеров.

Чтобы удовлетворить требования той или иной тактики или стратегии к моменту

принятия торгового решения, необходимо знать текущее состояние: какие рыночные и

отложенные ордера имеются и какие у них характеристики. Для этого можно

использовать один из двух вариантов решения.

В соответствии с первым вариантом необходимый фрагмент программного кода (в

котором выполняется анализ ордеров) прописывается непосредственно в том месте

программы, где нужно выяснить текущий набор ордеров и их характеристики. Такое

решение технически осуществимо, но оказывается неэффективным, когда необходимо

внести изменения в алгоритм. В этом случае программист вынужден анализировать все

места программы, где анализируется состояние ордеров, и вносить изменения в каждом

месте. Второй, более эффективный вариант решения, заключается в том, чтобы один раз

создать универсальную функцию учёта ордеров и использовать её всякий раз, когда

требуется обновить информацию о текущем состоянии ордеров. Такое решение, с одной

стороны, позволяет значительно сократить код программы, а с другой стороны,

предоставляет программисту возможность использовать готовую функцию при

составлении других программ.

Для того чтобы правильно составить функцию учёта ордеров, необходимо решить, какие

параметры нужно учитывать. В большинстве случаев для принятия торговых решений

требуются значения следующих параметров:

общее количество ордеров;

количество ордеров каждого типа (например, сколько имеется ордеров Buy, сколько

SellStop, BuyLimit и т.д.);

все характеристики каждого из ордеров (номер ордера, StopLoss и TakeProfit ордера,

количество лотов и т.д.).

Указанная информация должна быть доступна другим функциям, а именно тем, в которых

эта информация обрабатывается. По этой причине все параметры, характеризующие

состояние ордеров, являются значениями глобальных массивов. Всего для учёта ордеров

предусмотрено три массива:

877

массив текущих ордеров Mas_Ord_New, содержащий сведения обо всех характеристиках

всех рыночных и отложенных ордеров, имеющихся на текущий момент, а именно, в

период последнего исполнения функции;

массив старых ордеров Mas_Ord_Old, содержащий сведения обо всех характеристиках

всех рыночных и отложенных ордеров, имеющихся на момент предыдущего исполнения

функции;

массив Mas_Tip, значениями которого являются количества ордеров различных типов (на

текущий момент).

Массивы Mas_Ord_New и Mas_Ord_Old подобны и имеют одинаковую размерность;

разница между ними заключается лишь в том, что первый из них отражает текущее

состояние ордеров, а второй - предшествующее. Рассмотрим детально, какие значения

содержатся в элементах этих массивов.

Таблица 4. Соответствие элементов массивов Mas_Ord_New и Mas_Ord_Old

характеристикам ордеров.

Не

опред.

Курс

открытия

StopLoss

TakeProfi

t

Номер

ордера

Колич.

лотов

Тип

ордера

Magic

Number

Коммент.

Индексы0 1 2 3 4 5 6 7 8

0 2.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0

1 0.0 1.2583 1.2600 1.2550 123456.01.4 1.0

1177102416.

0

1.0

2 0.0 1.2450 1.2580 1.2415 123458.02.5 2.0

1177103358.

0

0.0

3 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0

. . . 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0

30 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0

Первый индекс массива (строки) определяет порядковый номер ордера в массиве.

Характеристики первого обнаруженного ордера (среди открытых рыночных и

установленных отложенных ордеров) заносятся в первую строку массива, второго ордера -

878

во вторую строку и т.д. Размер массива по первому индексу равен 31, таким образом,

массив предназначен для хранения информации максимум о тридцати ордерах,

одновременно присутствующих в торговле по одному торговому счёту. В случае, если

торговая стратегия допускает наличие одновременно более тридцати ордеров, то при

объявлении массива необходимо указать соответствующее значение для первого индекса.

(В подавляющем большинстве случаев значение 30 значительно превышает

действительную потребность, которая может составлять от 2 до 10-15. Здесь для примера

используется значение 30, принятое с большим запасом, в предположении, что функция

может использоваться и в случае реализации своеобразной торговой стратегии).

Второй индекс массива (столбцы) соответствует характеристикам ордеров. Каждый

элемент массива со вторым индексом, равным 1, содержит значение курса открытия

ордера, с индексом 2 - значение StopLoss ордера, 3 - TakeProfit ордера и т.д. (см. Таблицу

4). Элемент массива с индексом [0][0] имеет значение, равное общему количеству

ордеров, содержащихся в массиве. Все элементы массива с первым или вторым индексом,

равным 0, не используются (кроме элемента с индексом [0][0]).

В таблице 4 показано состояние массива, содержащего информацию о двух ордерах, в

некоторый момент времени одновременно присутствующих в торговле. Элемент массива

Mas_Ord_New[0][0] имеет значение 2.0 - общее количество ордеров - два. Элементы

первой строки массива содержат значения характеристик рыночного ордера Sell

(Mas_Ord_New[1][6] = 1.0, см. Типы торговых операций), открытого на 1.4 лота

(Mas_Ord_New[1][5] =1.4), имеющего номер 123456 (Mas_Ord_New[1][4] =123456.0).

Значение элемента Mas_Ord_New[1][8] =1.0 означает, что этот ордер имеет непустой

комментарий. Во второй строке массива содержатся значения, характеризующие второй

ордер. В частности, элемент массива Mas_Ord_New[2][6] имеет значение 2.0, - значит, это

ордер BuyLimit.

Массив Mas_Tip отражает количество ордеров каждого типа. Значения индексов этого

массива поставлены в соответствие типам торговых операций (см. Типы торговых

операций). Это означает, что элемент массива Mas_Tip с индексом 0 содержит количество

одновременно присутствующих в торговле рыночных ордеров типа Buy, с индексом 1 -

ордеров типа Sell, с индексом 2 - типа BuyLimit и т.д. Для ситуации, отражённой в таблице

4, элементы массива Mas_Tip будут иметь следующие значения:

Таблица 5. Соответствие элементов массива Mas_Tip количеству ордеров различных

типов.

879

Buy Sell BuyLimit SellLimit BuyStop SellStop

Индекс 0 1 2 3 4 5

Значение 0 1 1 0 0 0

В данном случае значения элементов массива Mas_Tip означают следующее: Mas_Tip[1]

равно 1, значит, в торговле имеется один ордер Sell; Mas_Tip[2] также равно 1, значит, в

торговле есть один отложенный ордер BuyLimit. Остальные элементы массива имеют

нулевые значения, значит ордеров этого типа в торговле нет. В случае если в торговле

присутствуют одновременно несколько ордеров одного типа, то соответствующий

элемент массива будет иметь значение, равное количеству таких ордеров. Например, если

в торговле имеется три ордера BuyStop, то элемент Mas_Tip[4] будет иметь значение 3.

Предлагаемая здесь функция учёта ордеров Terminal() оформлена в виде включаемого

файла Terminal.mqh.

13.2.1 Пользовательская функция Terminal()

int Terminal()

Функция выполняет учёт рыночных и отложенных ордеров. В результате исполнения

функции изменяются значения следующих глобальных массивов:

Mas_Ord_New - массив характеристик ордеров, имеющихся на момент исполнения

функции;

Mas_Ord_Old - массив характеристик ордеров, имеющихся на момент предыдущего

исполнения функции;

Mas_Tip - массив количества ордеров всех типов.

Включаемый файл Terminal.mqh, содержащий описание функции учёта ордеров

Terminal():

//--------------------------------------------------------------------

// Terminal.mqh

// Предназначен для использования в качестве примера в учебнике MQL4.

//--------------------------------------------------------------- 1 --

// Функция учёта ордеров

// Глобальные переменные:

// Mas_Ord_New[31][9] // Массив ордеров последний известный

// Mas_Ord_Old[31][9] // Массив ордеров предыдущий (старый)

// 1й индекс = порядковый номер ордера

880

Язык программирования MQL4

Подождите немного. Документ загружается.